$PROB Warfarin PKPD

;O'Reilly RA, Aggeler PM, Leong LS. Studies of the coumarin anticoagulant

;drugs: The pharmacodynamics of warfarin in man.

;Journal of Clinical Investigation 1963;42(10):1542-1551

 

;O'Reilly RA, Aggeler PM. Studies on coumarin anticoagulant drugs

;Initiation of warfarin therapy without a loading dose.

;Circulation 1968;38:169-177

 

$INPUT ID time wt age sex amt dvid dv mdv

$DATA warfarin_conc_pca.csv

$EST METHOD=COND INTER 

MAX=9990 NSIG=3 SIGL=9 PRINT=1 NOABORT

$COV

 

$THETA

(0.01,0.134,1) ; POP_CL L/h/70kg

(0.01,8.1,20) ; POP_V L/70kg

(0.01,0.575,24) ; POP_TABS h

(0.01,0.815,24) ; POP_LAG h

(0.01,96.7,200) ; POP_S0

(-1,-1.,0) FIX ; POP_EMAX

(0.01,1.2,10) ; POP_C50

(0.01,12.9,100) ; POP_TEQ

 

$OMEGA

0.0638 ; PPV_CL

0.0168 ; PPV_V

0.691 ; PPV_TABS

0.155 ; PPV_LAG

0.00377 ; PPV_S0

0 FIX ; PPV_EMAX

0.21 ; PPV_C50

0.0165 ; PPV_TEQ

 

$SIGMA

0.0133 ; RUV_CV

0.05 ; RUV_SD mg/L

15.3 ; RUV_FX

 

$SUBR ADVAN6 TOL=3

$MODEL

   COMP=GUT

   COMP=CENTRAL

   COMP=PCA

$PK

 

   IF (NEWIND.LE.1) LN2=LOG(2)

 

   FSZV=WT/70

   FSZCL=FSZV**0.75

 

   CL=FSZCL*POP_CL*EXP(PPV_CL)

   V=FSZV*POP_V*EXP(PPV_V)

   TABS=POP_TABS*EXP(PPV_TABS)

   TLAG=POP_LAG*EXP(PPV_LAG)

 

   S0=POP_S0*EXP(PPV_S0)

   EMAX=POP_EMAX*EXP(PPV_EMAX)

   C50=POP_C50*EXP(PPV_C50)

   TEQ=POP_TEQ*EXP(PPV_TEQ)

 

   IF (EMAX.LT.-1) EXIT 1 101

 

   KA=LN2/TABS

   ALAG1=TLAG

   S2=V

   A_0(3)=S0

   KPCA=LN2/TEQ

   RPCA=S0*KPCA

 

$DES

   RATEIN=KA*A(1)

   DCP=A(2)/V

   DPCA=A(3)

   PD=1+EMAX*DCP/(C50+DCP)

 

   DADT(1)=-RATEIN

   DADT(2)=RATEIN - CL*DCP

   DADT(3)=RPCA*PD - KPCA*DPCA

 

$ERROR

 

   CP=A(2)/V

   PCA=A(3)

   IF (DVID.LE.1) THEN

      Y=CP*(1+RUV_CV) + RUV_SD

   ENDIF

   IF (DVID.EQ.2) THEN

      Y=PCA + RUV_FX

   ENDIF

 

$TABLE ID TIME DVID CP PCA Y

ONEHEADER NOPRINT FILE=ka1.fit